\CANCEL MODE verify

! set initial demo state
CANCEL DATA/ALL
CANCEL REGION

! dods_demo.jnl  *kob* 5/99
! customized for IPRC presentation 9/99 *sh*
!
! Description: Demo: how to use Ferret and DODS to access remote Datasets
!

SET MODE verify




!      *********************************************************
!        DEMO: Using Ferret and DODS to access remote data sets
!      *********************************************************

! First we will examine the COADS climatology dataset from the Pacific
! Marine Environmental Laboratory (PMEL) in Seattle, Washington. 


! Note:  Once the dataset has been initialized from the remote site,
!        using the dataset is exactly the same as if it were local


PAUSE
!      *********************************************************

USE "http://ferret.pmel.noaa.gov/thredds/dodsC/data/PMEL/coads_climatology.nc"
SHOW DATA

! SHOW DATA verifies that this is indeed a remote dataset
! 
! Now let's look at a color contour of Sea Surface Temperature


PAUSE
!      *********************************************************

FILL/T="16-jul" sst
GO land

! Next, let's look at a subregion of the SST. 
 
!   Note: Higher data access speed may be noticed due to data caching by Ferret



PAUSE
!      *********************************************************

GO basemap X=130E:170W Y=30N:70N 20
FILL/OVERLAY/T="16-jul"/X=140E:180E/Y=40N:65N sst

! Remote data has full random access. Here we will plot the evolution of SST
! averaged over the Equatorial waveguide (an XT section)

PAUSE
!      *********************************************************


FILL/X=140E:180E/L=1:24 sst[Y=5S:5N@AVE]

! Now, let's use a different dataset, with ocean temperature, the NODC World Ocean Atlas 1998   
! computed by Levitus and served by the Climate Diagnostics Center (CDC) in Boulder, Colorado

PAUSE
!      *********************************************************

USE "http://www.cdc.noaa.gov/cgi-bin/opendap/nph-nc/Datasets/nodc.woa98/temperat/monthly/otemp.anal1deg.nc"

SHOW DATA 2

! This data set contains monthly mean global grids at a number of depths

! Let's look at the surface temperature for June, in the
! North Atlantic

PAUSE
!      *********************************************************

FILL/T="15-jun-1998"/Z=0/X=80W:20E/Y=0:80N otemp[D=2]
GO FLAND 20

PAUSE
!      *********************************************************

! Now, let's see where the NOCD field (served from Boulder)
! exceeds the June COADS climatological data (served from Seattle)

! This requires regridding the 2x2 degree COADS data to the 1x1 degree
! NODC grid

PAUSE
!      *********************************************************

LET coads_on_nodc = SST[D=1,G=otemp[D=2]]
LET warmer = IF otemp[D=2,Z=0] GT coads_on_nodc THEN 1
SHADE/X=80W:20E/Y=0:80N/PAL=black/LEVELS/PATTERN=weave/T="15-jun-1998"/OVER warmer
PAUSE

! Next lets examine some topography data serfved by the IRI/LDEO Climate Data Library
! at Columbia University (IRI/LDEO). This
! data is in the form of a 7200*3000 pixel image (some 20 megabytes)

! We will use this to illustrate the ability of Ferret and DODS to
! subsample -- making the data transfer much faster. For graphics, we
! don't have 7200x3000 pixels to show anyway!

PAUSE
!      *********************************************************

USE "http://ingrid.ldeo.columbia.edu/SOURCES/.USTOPO/dods"

! Performance greatly enhanced through use of strides
SHADE/LEV=(0,100,10)(100,1000,100)(1000,4000,400)(inf)/PALETTE=topo topo[I=1:7200:12, J=1:3000:8]